DataGrip的自动代码生成

24 8月

DataGrip

DataGrip是一款数据库客户端工具,是大名鼎鼎的JetBrains公司出品的,相信大部分程序员都用过同公司的Intellij IDEA。

DataGrip可以连接到数据库服务器,执行sql、管理表(创建表,修改索引等等)以及导出数据等。之前一直用的免费的MySQL Workbench,这个工具是免费的,能够满足日常需求,但是在Mac上经常死机,还有就是自动感应不是很灵敏。另外一个缺陷是专为MySQL设计。

想着因为是Apache committer的原因Jetbrains的全线产品免费,就尝试了一下DataGrip。

DataGrip和Intellij IDEA是一个壳子的,所以从样式,布局都是一样的,熟悉感很重,特别是两个软件切换来切换去的时候特别容易搞混。

DataGrip对于数据库的支持很宽泛,从PostgreSQL到MySQL再到Oracle这些都支持(其实我平时只用到了MySQL)。虽然官方没有说支持Hive数据库,但是实际上可以自定义driver和datasource,也可以用。

代码自动生成

这里的代码自动生成就是指数据库相关的Java代码或者MyBatis mapper可以自动生成。

代码自动生成对于效率的提升是很大的,不光是时间上的节约,还有一些就是代码准确度的提升。从纯工程实践的角度讲,给予成熟模版生成的代码绝对是一个很划算的买卖。特别对于一些完全没有技术含量的活,代码自动生成尤为重要。

现在很多代码自动生成都是基于Velocity 模板引擎来做的,也就是说代码的情况完全看模版,如果有需要可以修改模版(前提是工具或者扩展允许修改)。

Mybatis自带生成器,也有maven插件,但是灵活性一般,而且配置比较繁琐。

DataGrip的脚本扩展

DataGrip在2017.01版开始提供脚本扩展,支持groovy和cli。用法很直接,选中一个表,右键执行对应的脚本就行了。

网上能找到一些脚本,但是更多时候需要自己修改以符合公司内部规范或者项目组的一般规范,不过脚本扩展的优势就是比较容易修改,不过可读性其实比不过模板生成的模式。

DataGrip自带了一个生成Pojo的groovy脚本,可以直接用,不过那个脚本不会自动添加注释,自己稍加修改就好了。

脚本扩展的例子

import com.intellij.database.model.DasTable
import com.intellij.database.model.ObjectKind
import com.intellij.database.util.Case
import com.intellij.database.util.DasUtil

/*
 * Available context bindings:
 *   SELECTION   Iterable<DasObject>
 *   PROJECT     project
 *   FILES       files helper
 */

packageName = "com.sample;"
typeMapping = [
  (~/(?i)bigint/)                      : "Long",
  (~/(?i)int/)                      : "Integer",
  (~/(?i)float|double|decimal|real/): "java.math.BigDecimal",
  (~/(?i)datetime|timestamp/)       : "java.util.Date",
  (~/(?i)date/)                     : "java.util.Date",
  (~/(?i)time/)                     : "java.util.Date",
  (~/(?i)/)                         : "String"
]

FILES.chooseDirectoryAndSave("Choose directory", "Choose where to store generated files") { dir ->
  SELECTION.filter { it instanceof DasTable && it.getKind() == ObjectKind.TABLE }.each { generate(it, dir) }
}

def generate(table, dir) {
  def className = javaName(table.getName(), true)
  def fields = calcFields(table)
  new File(dir, className + ".java").withPrintWriter { out -> generate(out, className, fields) }
}

def generate(out, className, fields) {
  out.println "package $packageName"
  out.println ""
  out.println ""
  out.println "public class $className implements java.io.Serializable{"
  out.println ""
  fields.each() {
    out.println ""
    out.println "  /**"
    out.println "   * ${it.comment}"
    out.println "   */"
    if (it.annos != "") out.println "  ${it.annos}"
    out.println "  private ${it.type} ${it.name};"
  }
  out.println ""
  fields.each() {
    out.println ""
    out.println "  public ${it.type} get${it.name.capitalize()}() {"
    out.println "    return ${it.name};"
    out.println "  }"
    out.println ""
    out.println "  public void set${it.name.capitalize()}(${it.type} ${it.name}) {"
    out.println "    this.${it.name} = ${it.name};"
    out.println "  }"
    out.println ""
  }
  out.println "}"
}

def calcFields(table) {
  DasUtil.getColumns(table).reduce([]) { fields, col ->
    def commentStr = col.getComment()
    def spec = Case.LOWER.apply(col.getDataType().getSpecification())
    def typeStr = typeMapping.find { p, t -> p.matcher(spec).find() }.value
    fields += [[
                 name : javaName(col.getName(), false),
                 type : typeStr,
                 annos: "",
                 comment : commentStr]]
  }
}

def javaName(str, capitalize) {
  def s = com.intellij.psi.codeStyle.NameUtil.splitNameIntoWords(str)
    .collect { Case.LOWER.apply(it).capitalize() }
    .join("")
    .replaceAll(/[^\p{javaJavaIdentifierPart}[_]]/, "_")
  capitalize || s.length() == 1? s : Case.LOWER.apply(s[0]) + s[1..-1]
}

 

参考

https://www.jetbrains.com/datagrip/

https://www.jetbrains.com/help/datagrip/2017.1/extending-the-datagrip-functionality.html?search=extending

http://www.mvnrepository.com/artifact/org.apache.hive/hive-jdbc/3.1.0

https://www.ibm.com/developerworks/cn/java/j-lo-velocity1/index.html

发表评论

电子邮件地址不会被公开。